USE [GrpInsurance]
GO

/****** Object:  StoredProcedure [dbo].[proc_Rep10367]    Script Date: 10/07/2015 17:49:45 ******/
SET ANSI_NULLS ON
GO

SET QUOTED_IDENTIFIER ON
GO


-- last modified by Pribadi Pamungkas, 2015-10-07
ALTER PROCEDURE [dbo].[proc_Rep10367]
      @GroupPrs VARCHAR(5),
      @GTOG INT,
      @NoProposal VARCHAR(9),
      @TglMulai1 DATETIME,
      @TglMulai2 DATETIME,
      @TglSelesai1 DATETIME,
      @TglSelesai2 DATETIME,
      @TglMulai1Ya BIT,
      @TglMulai2Ya BIT,
      @TglSelesai1Ya BIT,
      @TglSelesai2Ya BIT
AS 
SET NOCOUNT ON

---- start: Hitung jumlah ERP untuk no proposal periode sebelumnya ------------------------------------------------------
DECLARE @jml_erp_tahun_lalu FLOAT = 0.0

IF (COALESCE(@NoProposal,'')<>'') -- jika no_proposal tidak kosong
  BEGIN
  
    -- no proposal tahun sebelumnya
    DECLARE @no_proposal_sebelumnya VARCHAR(9)
    SELECT
	    @no_proposal_sebelumnya = sblm.No_Proposal
    FROM
	    dbo.Polis_Asuransi AS skrng INNER JOIN
	    dbo.Polis_Asuransi AS sblm ON skrng.No_Polis = sblm.No_Polis
	                                  AND (skrng.Tahun_Ke - 1) = sblm.Tahun_Ke
    WHERE
      skrng.No_Proposal = @NoProposal
    
    IF (COALESCE(@no_proposal_sebelumnya,'')<>'') -- jika no_proposal tahun sebelumnya ada
      BEGIN
        DECLARE @ERP_sblm TABLE
        (
           Nama_Perusahaan VARCHAR(100),
           Erp_Prosen FLOAT,
           Adm_Erp FLOAT,
           Jml_Premi FLOAT,
           Diskon_Pr FLOAT,
           Premi_Net FLOAT,
           Jml_Dibayar FLOAT,
           Jml_Adm FLOAT,
           tagihan_lalu FLOAT,
           Jml_Beban FLOAT,
           Jml_Erp FLOAT
        )

        INSERT INTO @ERP_sblm
        EXEC	[dbo].[proc_Rep10367_hitung]
		        @GroupPrs,
		        @GTOG,
		        @no_proposal_sebelumnya,
		        @TglMulai1,
		        @TglMulai2,
		        @TglSelesai1,
		        @TglSelesai2,
		        0, -- @TglMulai1Ya
		        0, -- @TglMulai2Ya
		        0, -- @TglSelesai1Ya
		        0  -- @TglSelesai2Ya

        DECLARE 
          @jml_ERP_sblm FLOAT = 0.0
        SELECT
          @jml_ERP_sblm = SUM(Jml_Erp)
        FROM
	        @ERP_sblm
	        
	      IF COALESCE(@jml_ERP_sblm,0)<0
	        SET @jml_erp_tahun_lalu = ABS(@jml_ERP_sblm)
	      ELSE
	        SET @jml_erp_tahun_lalu = 0.0

      END
  END
---- end: Hitung jumlah ERP untuk no proposal periode sebelumnya ------------------------------------------------------


---- start: Hitung jumlah ERP untuk no proposal seperti pada parameter ------------------------------------------------------
DECLARE @ERP_sekarang TABLE
(
   Nama_Perusahaan VARCHAR(100),
   Erp_Prosen FLOAT,
   Adm_Erp FLOAT,
   Jml_Premi FLOAT,
   Diskon_Pr FLOAT,
   Premi_Net FLOAT,
   Jml_Dibayar FLOAT,
   Jml_Adm FLOAT,
   tagihan_lalu FLOAT,
   Jml_Beban FLOAT,
   Jml_Erp FLOAT
)

INSERT INTO @ERP_sekarang
EXEC	[dbo].[proc_Rep10367_hitung]
    @GroupPrs,
    @GTOG,
    @NoProposal,
    @TglMulai1,
    @TglMulai2,
    @TglSelesai1,
    @TglSelesai2,
    0, -- @TglMulai1Ya
    0, -- @TglMulai2Ya
    0, -- @TglSelesai1Ya
    0  -- @TglSelesai2Ya

---- end: Hitung jumlah ERP untuk no proposal seperti pada parameter ------------------------------------------------------


UPDATE
  @ERP_sekarang
SET
  tagihan_lalu = @jml_erp_tahun_lalu

SELECT
	*
FROM
	@ERP_sekarang
	

GO


